Talk:Calculate Results from a Model/Notes

<< Back to Tutorials Main Page

In Synthesis applications, models can represent the reliability of a component, the duration of a task, the expected cost of a repair and many other characteristics. In this tutorial, you'll learn how to calculate a variety of useful metrics from models.

Prerequisites

Before you begin:

• Create a test repository (can use Weibull++, ALTA, BlockSim or RGA). Perform a simple analysis and then publish a model of the analysis. You'll want to use a published model with this tutorial so you can compare the results returned by the API with the results obtained from the Quick Calculation Pad (QCP).

• Note the published model's object ID number. You will use the ID# to retrieve the model from the database. (To display the object IDs, choose File > Application Setup, then click Other under the Synthesis Settings heading in the navigation panel. Select the Display Object IDs check box. The object ID of the model is displayed in the Resource Manager.)

Tutorial: Calculate Results from a Model

The following example demonstrates how to obtain calculated results from a model resource. A discussion of the example follows.

A VBA version of the code sample is available here.

VB.NET

Imports SynthesisAPI 

 Module Module1
    Sub Main()
  
    'Connect to a Synthesis repository and project. 
     Dim MyRepository As New Repository
     MyRepository.ConnectToRepository("C:\RSRepository1.rsr10") 'Replace with name and path to test repository. 
     MyRepository.Project.SetCurrentProject(1) 'Replace with the object ID of test project. 

    'Retrieve a model from the repository.       
     Dim AModel As cModel
     AModel = MyRepository.Model.GetModel(21) 'Replace with the object ID of test model. 
  
    'Declare some variables to store the results. 
     Dim Result1 As Double
     Dim Result2 As Double

    'Calculate the model's reliability at time = 100 hrs and mean time. 
     Result1 = AModel.Reliability(100)
     Result2 = AModel.MeanTime

    'Set the confidence level to 90% two-sided bounds. 
    'Declare a string variable for any errors found during this method. 
     Dim ErrorMsg As String
     AModel.SetConfidenceLevel(0.9, ConfBoundsSides.TwoSidedBoth, False, ErrorMsg)

    'Declare new BoundsValues objects to store the confidence bounds results. 
     Dim BResult1 As BoundsValues
     Dim BResult2 As BoundsValues

    'Calculate bounds for the reliability at 100 hrs and the mean time. 
     BResult1 = AModel.Bounds_Reliability(100)
     BResult2 = AModel.Bounds_MeanTime

    'Display the output. 
     MsgBox ("Reliability = " & Result1 & vbNewLine & _
             "Upper Bound = " & BResult1.upper & vbNewLine & _
             "Lower Bound = " & BResult1.lower & vbNewLine)
     MsgBox ("Mean Time = " & Result2 & vbNewLine & _
             "Upper Bound = " & BResult2.upper & vbNewLine & _
             "Lower Bound = " & BResult2.lower & vbNewLine)

    End Sub
End Module

Discussion

Begin by connecting to a Synthesis repository and project (for details, see this tutorial.) If you're copying this section of code, be sure to replace the inputs with appropriate data for your test repository.

 'Connect to a Synthesis repository and project. 
  Dim MyRepository As New Repository
  MyRepository.ConnectToRepository("C:\RSRepository1.rsr10") 'Replace with name and path to test repository. 
  MyRepository.Project.SetCurrentProject(1) 'Replace with the object ID of test project. 

Once you are connected to the repository, use the Model.GetModel method to retrieve a single model from the repository. The following code assumes that the repository contains a model with ID#21.

 'Retrieve a model from the repository.       
  Dim AModel As cModel
  AModel = MyRepository.Model.GetModel(21) 'Replace with the object ID of test model. 

We can now obtain some metrics from the model. The cModel Class reference doc lists all available methods for performing calculations on models, but for this example, we'll limit it to the Reliability and MeanTime methods.

 'Declare some variables to store the results. 
  Dim Result1 As Double
  Dim Result2 As Double

 'Calculate the model's reliability at time = 100 hrs and mean time. 
  Result1 = AModel.Reliability(100)
  Result2 = AModel.MeanTime

To calculate the confidence bounds, use the SetConfidenceLevel method to specify 90% two-sided confidence bounds.

 'Set the confidence level to 90% two-sided bounds. 
 'Declare a string variable for any errors found during this method. 
  Dim ErrorMsg As String
  AModel.SetConfidenceLevel(0.9, ConfBoundsSides.TwoSidedBoth, False, ErrorMsg)

And then use any of the bounds calculation methods in the class to perform the commands. Here, we limit the example to the Bounds_Reliability and Bounds_MeanTime methods.

 'Declare new BoundsValues objects to store the confidence bounds results. 
  Dim BResult1 As BoundsValues
  Dim BResult2 As BoundsValues

 'Calculate bounds for the reliability at 100 hrs and the mean time. 
  BResult1 = AModel.Bounds_Reliability(100)
  BResult2 = AModel.Bounds_MeanTime

The last section of code creates simple message boxes to display the outputs, allowing you to compare the results returned by the API with the results obtained from the software's Quick Calculation Pad (QCP).

 'Display the output. 
  MsgBox ("Reliability = " & Result1 & vbNewLine & _
         "Upper Bound = " & BResult1.upper & vbNewLine & _
         "Lower Bound = " & BResult1.lower & vbNewLine)
  MsgBox ("Mean Time = " & Result2 & vbNewLine & _
         "Upper Bound = " & BResult2.upper & vbNewLine & _
         "Lower Bound = " & BResult2.lower & vbNewLine)

References

• CModel Class
• cModel.Reliability Method
• cModel.MeanTime Method
• cModel.SetConfidenceLevel Method
• cModel.Bounds_Reliability Method
• cModel.Bounds_MeanTime Method
• BoundsValues Class