Edit Existing Synthesis Resources

<< Back to Tutorials Main Page

In the previous tutorial, you learned how to create new Synthesis resources (e.g., models, actions, URDs, etc.) and save them to a database. In this tutorial, you'll learn how to retrieve an existing Synthesis resource from a database, and then overwrite existing data about the resource with new information.

You'll use a model resource to work with the example. A similar approach can be used when working with other types of Synthesis resources.

Prerequisites

Before you begin:

• Create a Synthesis repository for testing purposes. Then create a model via the Resource Manager (Project > Synthesis> Resource Manager). Do not use published models for this tutorial (i.e., model resources that have been published from and are associated with an existing analysis/data source). Published models are read-only and therefore cannot be used to demonstrate the goals of this tutorial.

• Note down the model's object ID. You will use the object ID to retrieve the model from the database.

Tutorial: Edit an Existing Synthesis Resource

The following example demonstrates how to retrieve a Synthesis resource from a repository and overwrite existing data about the resource with new information. A discussion of the example follows.

A VBA version of the code sample is available here.

VB.NET

Imports SynthesisAPI 

Public Module Module1
   Sub Main()
 
   'Connect to a Synthesis repository and project. 
    Dim MyRepository As New Repository
    MyRepository.ConnectToRepository("C:\RSRepository1.rsr11") 'Replace with name and path to test repository. 
    MyRepository.Project.SetCurrentProject(1) 'Replace with the object ID of test project. 
  
   'Declare a new cModel object.  
    Dim Amodel As New cModel

   'Retrieve a model from the project.  
    AModel = MyRepository.Model.GetModel(21) 'Replace with the object ID of test model. 

   'Edit the model's name, description and part number. 
    Amodel.Name = "MyNewModel_Updated"
    Amodel.ItemDescription = "A specific type of light bulb."
    Amodel.ItemPartNumber = "PN5461"   

   'Send the changes to the project. 
    MyRepository.Model.UpdateModel(AModel)

   End Sub
End Module

Discussion

Begin by connecting to a Synthesis repository and project (for details, see this tutorial.) The example below demonstrates how to connect to a standard repository and open one of its projects. It assumes that a standard repository called "RSRepository1.rsr11" exists in the C drive and that we're accessing project ID#1. If you're copying this section of code, be sure to replace the inputs with appropriate data for your test repository.

 'Connect to a Synthesis repository and project. 
  Dim MyRepository As New Repository
  MyRepository.ConnectToRepository("C:\RSRepository1.rsr11") 'Replace with name and path to test repository. 
  MyRepository.Project.SetCurrentProject(1) 'Replace with the object ID of test project. 

Once you are connected to the repository, use the Model.GetModel method to retrieve a single model from the repository. The following code assumes that the repository contains a model with ID#21.

 'Declare a new cModel object.  
  Dim Amodel As New cModel

 'Retrieve a model from the project.  
  AModel = MyRepository.Model.GetModel(21) 'Replace with the object ID of test model. 

You can then edit the model's properties. In this example, we edited the model's name, description and part number, as shown. (To update a model's parameters, category or type, use the cModel.SetModel method.)

 'Edit the model's name, description and part number. 
  Amodel.Name = "MyNewModel_Updated"
  Amodel.ItemDescription = "A specific type of light bulb."
  Amodel.ItemPartNumber = "PN5461"   

Use the Model.UpdateModel method to save the new information to the Synthesis repository.

 'Send the changes to the project. 
  MyRepository.Model.UpdateModel(AModel)

To verify that the model's properties have been updated, open the Resource Manager and look up the model. You may need to display the Description and Part Number columns of the Resource Manager by right-clicking a column header and choosing Select Columns.

Notes

• To retrieve all other types of Synthesis resources, you can use the same approach demonstrated in the example. For example, to update the properties of an existing URD, you would use the Repository.URD.GetURD method to retrieve a single URD from the repository, and then use the Repository.URD.UpdateURD method to apply the changes.

• To perform batch updates, use the Repository.Model.GetAllModels method to get an array of all available models in the repository. Similar methods exist for all other types of Synthesis resources (e.g., Repository.URD.GetAllURDs, Repository.Action.GetAllActions, etc.). See the Repository Class reference documentation for the complete list.

References

• Repository Class
  • Repository.Model.GetModel Method
  • Repository.Model.UpdateModel Method